blob: 30d87e469279229313468ac30185e3dcf0e2df05 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic
DESCRIPTION="A full featured backup tool, aimed for disks"
HOMEPAGE="http://dar.linux.free.fr/"
SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
IUSE="argon2 curl dar32 dar64 doc gcrypt gpg lz4 lzo nls rsync threads xattr"
REQUIRED_USE="?? ( dar32 dar64 )
gpg? ( gcrypt )"
RESTRICT="test" # need to be run as root
RDEPEND="
app-arch/bzip2:=
app-arch/xz-utils
app-arch/zstd:=
sys-libs/libcap
>=sys-libs/zlib-1.2.3:=
argon2? ( app-crypt/argon2:= )
curl? ( net-misc/curl )
gcrypt? (
dev-libs/libgcrypt:0=
dev-libs/libgpg-error
)
gpg? ( app-crypt/gpgme:1= )
lz4? ( app-arch/lz4:= )
lzo? ( dev-libs/lzo:2 )
nls? ( virtual/libintl )
rsync? ( net-libs/librsync:= )
threads? ( dev-libs/libthreadar )
xattr? ( sys-apps/attr )
"
DEPEND="${RDEPEND}"
BDEPEND="
doc? ( app-doc/doxygen )
nls? ( sys-devel/gettext )
"
src_configure() {
# configure.ac is totally funked up regarding the AC_ARG_ENABLE
# logic.
# For example "--enable-dar-static" causes configure to DISABLE
# static builds of dar.
# Do _not_ use $(use_enable) until you have verified that the
# logic has been fixed by upstream.
local myconf=(
--disable-dar-static
--disable-python-binding
--disable-upx
$(usev !argon2 --disable-libargon2-linking)
$(usev !curl --disable-libcurl-linking)
$(usev dar32 --enable-mode=32)
$(usev dar64 --enable-mode=64)
$(usev !doc --disable-build-html)
$(usev !gcrypt --disable-libgcrypt-linking)
$(usev !gpg --disable-gpgme-linking)
$(usev !lz4 --disable-liblz4-linking)
$(usev !lzo --disable-liblzo2-linking)
$(usev !nls --disable-nls)
$(usev !rsync --disable-librsync-linking)
$(usev !threads --disable-threadar)
$(usev !xattr --disable-ea-support)
)
# Bug 103741
filter-flags -fomit-frame-pointer
econf "${myconf[@]}"
}
src_install() {
emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
einstalldocs
find "${ED}" -name "*.la" -delete || die
# Bug 729150
rm "${ED}/usr/share/doc/${PF}/html/samples/MyBackup.sh.tar.gz" || die
}
|
GitWeb