app-editors/tea/tea-62.1.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake xdg

MY_P="tea-qt-${PV}"

DESCRIPTION="Small, lightweight Qt text editor"
HOMEPAGE="https://tea.ourproject.org/"
SRC_URI="https://github.com/psemiletov/tea-qt/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~riscv ~x86"
IUSE="aspell djvu pdf"

# qt6 blocked by poppler[qt6]
DEPEND="
	app-text/hunspell:=
	dev-qt/qtcore:5
	dev-qt/qtgui:5
	dev-qt/qtwidgets:5
	sys-libs/zlib
	aspell? ( app-text/aspell )
	djvu? ( app-text/djvu )
	pdf? ( app-text/poppler:=[qt5] )
"
RDEPEND="${DEPEND}"
BDEPEND="virtual/pkgconfig"

DOCS=( AUTHORS ChangeLog NEWS NEWS-RU TODO )

PATCHES=(
	"${FILESDIR}/tea-62.1.1-qt-option.patch"
	"${FILESDIR}/tea-62.1.1-fix-desktop.patch"
)

src_prepare() {
	cmake_src_prepare

	# Replace AUR link with p.g.o link
	sed -i \
		-e 's,AUR: aur.archlinux.org/packages/tea-qt-git,Gentoo: https://packages.gentoo.org/packages/app-editors/tea,' \
		tea.cpp translations/{de,es,fr,pl,ru}.ts || die

	# Rename tea to tea-qt to avoid file conflict with dev-util/tea
	# bug #917587
	# https://github.com/psemiletov/tea-qt/issues/50
	sed -i -e '/set_target_properties(tea PROPERTIES$/ a\
		OUTPUT_NAME \"tea-qt\"' \
		CMakeLists.txt || die
	sed -i -e '/Exec/ { s/tea/tea-qt/ }' desktop/tea.desktop || die
}

src_configure() {
	local mycmakeargs=(
		-DUSE_ASPELL=$(usex aspell)
		-DUSE_PDF=$(usex pdf)
		-DUSE_DJVU=$(usex djvu)
		-DUSE_QT6=OFF # blocked by poppler-qt6
		-DUSE_PRINTER=OFF # only for qt6
	)

	cmake_src_configure
}

pkg_postinst() {
	xdg_pkg_postinst

	if [[ "${REPLACING_VERSIONS}" == "47.0.0" ]]; then
		elog "Executable 'tea' has been renamed to 'tea-qt'"
	fi
}