blob: f1690601d39239221bc1bff033b4e0dd24dfa034 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit ltprune multilib autotools flag-o-matic versionator
MY_P=${PN}-${PV/_beta/b}
DESCRIPTION="Hunspell spell checker - an improved replacement for myspell in OOo"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
HOMEPAGE="https://github.com/hunspell"
SLOT="0/$(get_version_component_range 1-2)"
LICENSE="MPL-1.1 GPL-2 LGPL-2.1"
IUSE="ncurses nls readline static-libs"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
RDEPEND="
ncurses? ( sys-libs/ncurses:0= )
readline? ( sys-libs/readline:= )"
DEPEND="${RDEPEND}
sys-devel/gettext"
LANGS="af bg ca cs cy da de de-1901 el en eo es et fo fr ga gl he hr hu ia id
is it kk km ku lt lv mi mk ms nb nl nn pl pt pt-BR ro ru sk sl sq sv sw tn uk
zu"
PDEPEND="app-dicts/myspell-en"
for lang in ${LANGS}; do
IUSE+=" l10n_${lang}"
case ${lang} in
de-1901) dict="de_1901" ;;
pt-BR) dict="pt-br" ;;
*) dict="${lang}" ;;
esac
PDEPEND+=" l10n_${lang}? ( app-dicts/myspell-${dict} )"
done
unset dict lang LANGS
S="${WORKDIR}/${MY_P}"
DOCS=(
AUTHORS ChangeLog NEWS README THANKS TODO license.hunspell
AUTHORS.myspell README.myspell license.myspell README.md
)
PATCHES=(
# Upstream package creates some executables which names are too generic
# to be placed in /usr/bin - this patch prefixes them with 'hunspell-'.
# It modifies a Makefile.am file, hence eautoreconf.
"${FILESDIR}/${PN}-1.6.2-renameexes.patch"
)
src_prepare() {
default
eautoreconf
}
src_configure() {
# missing somehow, and I am too lazy to fix it properly
[[ ${CHOST} == *-darwin* ]] && append-libs -liconv
# I wanted to put the include files in /usr/include/hunspell.
# You can do that, libreoffice can find them anywhere, just
# ping me when you do so ; -- scarabeus
local myeconfargs=(
$(use_enable nls)
$(use_with ncurses ui)
$(use_with readline readline)
$(use_enable static-libs static)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
einstalldocs
prune_libtool_files --all
#342449
pushd "${ED%/}"/usr/$(get_libdir)/ >/dev/null
ln -s lib${PN}{-$(get_major_version).$(get_version_component_range 2).so.0.0.1,.so}
popd >/dev/null
}
|
GitWeb