blob: 28647fcbc51ad8850e7686455dc680a2e1b2ac8b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit flag-o-matic toolchain-funcs
DESCRIPTION="C++ class library of cryptographic schemes"
HOMEPAGE="http://cryptopp.com"
SRC_URI="https://www.cryptopp.com/cryptopp${PV//.}.zip"
LICENSE="Boost-1.0"
SLOT="0/5.6" # subslot is so version
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
IUSE="static-libs"
DEPEND="app-arch/unzip"
S="${WORKDIR}"
PATCHES=(
"${FILESDIR}/${PN}-5.6.4-nonative.patch"
)
pkg_setup() {
export CXX="$(tc-getCXX)"
export LIBDIR="${EPREFIX}/usr/$(get_libdir)"
export PREFIX="${EPREFIX}/usr"
}
src_compile() {
# higher optimizations cause problems
replace-flags -O3 -O2
# ASM isn't Darwin/Mach-O ready, #479554, buildsys doesn't grok CPPFLAGS
[[ ${CHOST} == *-darwin* ]] && append-cxxflags -DCRYPTOPP_DISABLE_ASM
emake -f GNUmakefile all shared
}
src_test() {
# ensure that all test vectors have Unix line endings
local file
for file in TestVectors/* ; do
edos2unix "${file}"
done
if ! emake test; then
eerror "Crypto++ self-tests failed."
eerror "Try to remove some optimization flags and reemerge Crypto++."
die "emake test failed"
fi
}
src_install() {
default
# remove leftovers as build system sucks
rm -fr "${ED}"/usr/bin "${ED}"/usr/share/cryptopp
use static-libs || rm -f "${ED}${EPREFIX}"/usr/$(get_libdir)/*.a
# compatibility
dosym cryptopp "${EPREFIX}"/usr/include/crypto++
for f in "${ED}${EPREFIX}"/usr/$(get_libdir)/*; do
ln -s "$(basename "${f}")" "$(echo "${f}" | sed 's/cryptopp/crypto++/')" || die
done
}
pkg_preinst() {
# we switched directory to symlink
# make sure portage digests that
rm -fr "${EROOT}/usr/include/crypto++"
rm -fr "${EROOT}/usr/include/cryptopp"
}
|
GitWeb
