dev-perl/CDB_File/CDB_File-1.50.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DIST_AUTHOR=TODDR
DIST_VERSION=1.05
DIST_EXAMPLES=("examples/*")
inherit perl-module

DESCRIPTION="Perl extension for access to cdb databases"

SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"

# bug 787551: T::Fatal and T::Warnings needed
BDEPEND="
	virtual/perl-ExtUtils-MakeMaker
	test? (
		dev-perl/B-COW
		virtual/perl-File-Temp
		dev-perl/Test-Fatal
		virtual/perl-Test-Simple
		dev-perl/Test-Warnings
	)
"

# Parallel breaks
DIST_TEST="do"

src_prepare() {
	mkdir "${S}/examples" || die "Can't make examples dir"
	einfo "Moving bun-x.pl to examples/"
	cp "${S}/bun-x.pl" "${S}/examples/" || die "Can't copy example to examples/"
	perl_rm_files bun-x.pl
	perl-module_src_prepare
}

src_compile() {
	mymake=(
		"OPTIMIZE=${CFLAGS}"
	)
	perl-module_src_compile
}