dev-python/jaraco-path/jaraco-path-3.3.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_{7..9} pypy3 )

inherit distutils-r1

MY_P="${P/-/.}"
DESCRIPTION="Miscellaneous path functions"
HOMEPAGE="https://github.com/jaraco/jaraco.path/"
SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
S=${WORKDIR}/${MY_P}

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 arm arm64 ~hppa ~ia64 ~ppc ppc64 ~s390 ~sparc ~x86 ~x64-macos"

BDEPEND="
	dev-python/setuptools_scm[${PYTHON_USEDEP}]
	dev-python/toml[${PYTHON_USEDEP}]
"

distutils_enable_sphinx docs \
	">=dev-python/jaraco-packaging-8.2" \
	">=dev-python/rst-linker-1.9"
distutils_enable_tests pytest

src_prepare() {
	# use the py3.7+ built-in
	sed -i -e '/singledispatch/d' setup.cfg || die
	sed -i -e 's:from singledispatch:from functools:' jaraco/path.py || die

	distutils-r1_src_prepare
}

python_test() {
	pytest -vv tests || die "Tests failed with ${EPYTHON}"
}