blob: e6ae253469221d159a0fabffbac405da7497eed5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYTHON_COMPAT=( python3_{10..12} )
inherit bash-completion-r1 distutils-r1 pypi
DESCRIPTION="Get Things From One Computer To Another, Safely"
HOMEPAGE="
https://magic-wormhole.readthedocs.io/en/latest/
https://github.com/magic-wormhole/magic-wormhole/
https://pypi.org/project/magic-wormhole/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/autobahn-0.14.1[${PYTHON_USEDEP}]
dev-python/automat[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
dev-python/cryptography[${PYTHON_USEDEP}]
dev-python/humanize[${PYTHON_USEDEP}]
>=dev-python/iterable-io-1.0.0[${PYTHON_USEDEP}]
dev-python/noiseprotocol[${PYTHON_USEDEP}]
dev-python/pynacl[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
~dev-python/spake2-0.8[${PYTHON_USEDEP}]
>=dev-python/tqdm-4.13.0[${PYTHON_USEDEP}]
dev-python/twisted[ssl,${PYTHON_USEDEP}]
>=dev-python/txtorcon-18.0.2[${PYTHON_USEDEP}]
>=dev-python/zipstream-ng-1.7.1[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/magic-wormhole-mailbox-server[${PYTHON_USEDEP}]
~dev-python/magic-wormhole-transit-relay-0.2.1[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest
}
src_install() {
distutils-r1_src_install
newbashcomp "${ED}/usr/wormhole_complete.bash" wormhole
insinto /usr/share/fish/completions
newins "${ED}/usr/wormhole_complete.fish" wormhole.fish
insinto /usr/share/zsh/site-functions
newins "${ED}/usr/wormhole_complete.zsh" _wormhole
rm "${ED}/usr"/wormhole_complete* || die
}
|
GitWeb
