blob: ae8ba7216b15160e8f652b983a6bd7ecf8558339 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{3_6,3_7} )
inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg
DESCRIPTION="Gnome Settings Daemon"
HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
LICENSE="GPL-2+ LGPL-2+"
SLOT="0"
IUSE="+colord +cups debug elogind input_devices_wacom networkmanager smartcard systemd test +udev wayland"
REQUIRED_USE="
^^ ( elogind systemd )
input_devices_wacom? ( udev )
wayland? ( udev )
"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
# >=polkit-0.114 for ITS translation rules of .policy files
COMMON_DEPEND="
>=sci-geosciences/geocode-glib-3.10
>=dev-libs/glib-2.56:2
>=gnome-base/gnome-desktop-3.11.1:3=
>=gnome-base/gsettings-desktop-schemas-3.27.90
>=x11-libs/gtk+-3.15.3:3[X,wayland?]
>=dev-libs/libgweather-3.9.5:2=
colord? (
>=x11-misc/colord-1.0.2:=
>=media-libs/lcms-2.2:2 )
media-libs/libcanberra[gtk3]
>=app-misc/geoclue-2.3.1:2.0
>=x11-libs/libnotify-0.7.3
>=media-sound/pulseaudio-2[glib]
>=sys-auth/polkit-0.114
>=sys-power/upower-0.99:=
x11-libs/libX11
udev? ( dev-libs/libgudev:= )
wayland? ( dev-libs/wayland )
input_devices_wacom? ( >=dev-libs/libwacom-0.7
>=x11-libs/pango-1.20.0
x11-libs/gdk-pixbuf:2 )
smartcard? ( >=dev-libs/nss-3.11.2 )
cups? ( >=net-print/cups-1.4[dbus] )
networkmanager? ( >=net-misc/networkmanager-1.0 )
media-libs/alsa-lib
x11-libs/libXi
x11-libs/libXext
media-libs/fontconfig
"
# logind needed for power and session management, bug #464944
# gnome-session-3.27.90 and gdm-3.27.9 adapt to A11yKeyboard component removal (moved to shell dealing with it)
# dbus[user-session] for user services support (functional screen sharing setup)
RDEPEND="${COMMON_DEPEND}
gnome-base/dconf
elogind? ( sys-auth/elogind )
systemd? ( sys-apps/systemd
sys-apps/dbus[user-session] )
!<gnome-base/gnome-session-3.27.90
!<gnome-base/gdm-3.27.90
"
# rfkill requires linux/rfkill.h (and USE=udev), thus linux-headers dep, not os-headers. If this package wants to work on other kernels, we need to make rfkill conditional instead
DEPEND="${COMMON_DEPEND}
sys-kernel/linux-headers
dev-util/glib-utils
dev-util/gdbus-codegen
x11-base/xorg-proto
${PYTHON_DEPS}
test? (
$(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
$(python_gen_any_dep 'dev-python/dbusmock[${PYTHON_USEDEP}]')
gnome-base/gnome-session )
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
# Tests go a bit better in 3.26, but still fail some for me; revisit with 3.30+ (incompatible build system python needs until then as well)
#RESTRICT="!test? ( test )"
PATCHES=(
# Translation updates from gnome-3-30 branch
# Allow disabling udev and networkmanager on Linux
# Make colord and wacom optional
"${WORKDIR}"/patches/
)
python_check_deps() {
if use test; then
has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
has_version "dev-python/dbusmock[${PYTHON_USEDEP}]"
fi
}
pkg_setup() {
python-any-r1_pkg_setup
}
src_configure() {
local emesonargs=(
#-Dnssdb_dir # TODO: Is the default /etc/pki/nssdb path correct for our nss?
-Dudev_dir="$(get_udevdir)"
-Dalsa=true
$(meson_use udev gudev)
$(meson_use colord)
$(meson_use cups)
$(meson_use networkmanager network_manager)
$(meson_use udev rfkill)
$(meson_use smartcard)
$(meson_use input_devices_wacom wacom)
$(meson_use wayland)
)
meson_src_configure
}
src_install() {
meson_src_install
# Don't auto-suspend by default on AC power
insinto /usr/share/glib-2.0/schemas
doins "${FILESDIR}"/org.gnome.settings-daemon.plugins.power.gschema.override
}
src_test() {
virtx meson_src_test
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb