blob: 240720a09fce125fd3bad0e0fbed04a87a71af5e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} )
VALA_MIN_API_VERSION="0.52"
inherit gnome.org meson python-any-r1 vala virtualx
DESCRIPTION="Building blocks for modern adaptive GNOME applications"
HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
LICENSE="LGPL-2.1+"
SLOT="1"
IUSE="+introspection test +vala"
REQUIRED_USE="vala? ( introspection )"
KEYWORDS="amd64 ~arm arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc x86"
DEPEND="
>=dev-libs/glib-2.66:2
>=gui-libs/gtk-4.5.0:4[introspection?]
dev-libs/fribidi
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
RDEPEND="${DEPEND}"
BDEPEND="
${PYTHON_DEPS}
vala? ( $(vala_depend) )
>=dev-util/meson-0.59.0
dev-util/glib-utils
sys-devel/gettext
virtual/pkgconfig
"
src_prepare() {
use vala && vala_src_prepare
default
}
src_configure() {
local emesonargs=(
# Never use gi-docgen subproject
--wrap-mode nofallback
-Dprofiling=false
$(meson_feature introspection)
$(meson_use vala vapi)
-Dgtk_doc=false # we ship pregenerated docs
$(meson_use test tests)
-Dexamples=false
)
meson_src_configure
}
src_test() {
virtx meson_src_test --timeout-multiplier 2
}
src_install() {
meson_src_install
insinto /usr/share/gtk-doc/html
# This will install libadwaita API docs unconditionally, but this is intentional
doins -r "${S}"/doc/libadwaita-1
}
|
GitWeb
