blob: 6b149be7cd8b4a2d79a1cd4c0fa3184f75b64f73 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
inherit gnome.org gnome2-utils meson python-any-r1 vala virtualx xdg
DESCRIPTION="A lightweight, easy-to-use, feature-rich email client"
HOMEPAGE="https://wiki.gnome.org/Apps/Geary"
LICENSE="LGPL-2.1+ CC-BY-3.0 CC-BY-SA-3.0" # code is LGPL-2.1+, CC licenses for some icons
SLOT="0"
IUSE="test ytnef"
RESTRICT="!test? ( test )"
KEYWORDS="~amd64 ~arm64 ~x86"
# >=gspell-1.7 dep to ensure all libraries used use enchant:2
DEPEND="
>=dev-libs/glib-2.66:2
>=x11-libs/gtk+-3.24.23:3
>=net-libs/webkit-gtk-2.30:4=
>=dev-libs/gmime-3.2.4:3.0
>=dev-db/sqlite-3.24:3
x11-libs/cairo[glib]
app-text/enchant:2
>=dev-libs/folks-0.11:0=
>=app-crypt/gcr-3.10.1:0=
>=dev-libs/libgee-0.8.5:0.8=
net-libs/gnome-online-accounts
media-libs/gsound
>=app-text/gspell-1.7:=
>=dev-libs/icu-60:=
app-text/iso-codes
>=dev-libs/json-glib-1.0
>=gui-libs/libhandy-1.2.1:1=
>=dev-libs/libpeas-1.24.0[gtk]
>=app-crypt/libsecret-0.11
dev-libs/snowball-stemmer:=
>=net-libs/libsoup-2.48:2.4
>=dev-libs/libxml2-2.7.8:2
ytnef? ( >=net-mail/ytnef-1.9.3 )
"
RDEPEND="${DEPEND}
gnome-base/gsettings-desktop-schemas
"
BDEPEND="
${PYTHON_DEPS}
>=dev-libs/appstream-glib-0.7.10
dev-libs/libxml2
dev-util/itstool
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
test? ( net-libs/gnutls[tools] )
$(vala_depend)
x11-libs/gtk+:3[introspection]
net-libs/webkit-gtk:4[introspection]
dev-libs/gmime:3.0[vala]
app-crypt/gcr:0[introspection,vala]
dev-libs/libgee:0.8[introspection]
media-libs/gsound[vala]
app-text/gspell[vala]
gui-libs/libhandy:1[vala]
app-crypt/libsecret[introspection,vala]
net-libs/libsoup:2.4[introspection,vala]
"
PATCHES=(
"${FILESDIR}"/${PV}-Fix-accessibility-issues-with-initializer-of-constan.patch
"${FILESDIR}"/${PV}-Util.Cache.Lru-Workaround-missing-generic-type-argum.patch
"${FILESDIR}"/${PV}-Correct-the-conditional-comments-in-the-test-data.patch
)
src_prepare() {
vala_setup
gnome2_environment_reset
default
}
src_configure() {
local emesonargs=(
-Dprofile=release
-Drevno="${PR}"
-Dvaladoc=disabled
-Dcontractor=disabled
-Dlibunwind=disabled
$(meson_feature ytnef tnef)
)
meson_src_configure
}
src_test() {
virtx meson_src_test
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb