blob: b1ceb5b7a604fdf4c3b5e28164206396b52c32e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools flag-o-matic toolchain-funcs
DESCRIPTION="Utility to view many different types of images under X11"
HOMEPAGE="https://sioseis.ucsd.edu/xloadimage.html https://tracker.debian.org/pkg/xloadimage"
SRC_URI="
ftp://ftp.x.org/R5contrib/${P/-/.}.tar.gz
mirror://gentoo/${P}-gentoo-r1.diff.bz2
https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-fix-build-for-clang16.patch.xz
"
S="${WORKDIR}"/${P/-/.}
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="tiff jpeg png"
RDEPEND="x11-libs/libX11
tiff? ( media-libs/tiff:= )
png? ( media-libs/libpng:= )
jpeg? ( media-libs/libjpeg-turbo:= )
!media-gfx/xli"
DEPEND="${RDEPEND}"
PATCHES=(
"${WORKDIR}"/${P}-gentoo-r1.diff
"${FILESDIR}"/${P}-zio-shell-meta-char.diff
"${FILESDIR}"/${P}-endif.patch
# Do not define errno extern, but rather include errno.h
# <azarah@gentoo.org> (1 Jan 2003)
"${FILESDIR}"/${P}-include-errno_h.patch
"${FILESDIR}"/xloadimage-gentoo.patch
"${FILESDIR}"/${P}-unaligned-access.patch
"${FILESDIR}"/${P}-ldflags_and_exit.patch
"${FILESDIR}"/${P}-libpng15.patch
"${WORKDIR}"/${P}-fix-build-for-clang16.patch
# One of the previous patches screws up a bracket...
"${FILESDIR}"/${P}-bracket.patch
)
src_prepare() {
default
sed -i -e "s:OPT_FLAGS=:OPT_FLAGS=$CFLAGS:" Make.conf || die
sed -i -e "s:^#include <varargs.h>:#include <stdarg.h>:" rlelib.c || die
# qa-sed sees no-op on the next sed on non-gentoo-prefix systems,
# but that is alright
sed -i -e "/^DEFS = /s:/etc:${EPREFIX}/etc:" Makefile.in || die
sed -i \
-e 's:png_set_gray_1_2_4_to_8:png_set_expand_gray_1_2_4_to_8:' \
png.c || die
eautoreconf
}
src_configure() {
# Set TIFFHeader to TIFFHeaderCommon wrt #319383
has_version '>=media-libs/tiff-4.0.0_pre' && \
append-flags -DTIFFHeader=TIFFHeaderCommon
tc-export CC
econf $(use_with jpeg) \
$(use_with png) \
$(use_with tiff)
}
src_compile() {
emake SYSPATHFILE="${EPREFIX}"/etc/X11/Xloadimage
}
src_install() {
dobin xloadimage uufilter
dosym xloadimage /usr/bin/xsetbg
dosym xloadimage /usr/bin/xview
insinto /etc/X11
doins xloadimagerc
newman xloadimage.man xloadimage.1
newman uufilter.man uufilter.1
echo ".so man1/xloadimage.1" > "${T}"/xsetbg.1 || die
doman "${T}"/xsetbg.1
newman "${T}"/xsetbg.1 xview.1
dodoc README
}
|
GitWeb