blob: a49d749b0a345fc85b50201cd4cc6fa4d7fd4e68 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils libtool multilib-minimal
DESCRIPTION="Portable Network Graphics library"
HOMEPAGE="http://www.libpng.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
LICENSE="libpng"
SLOT="0/16"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
IUSE="apng cpu_flags_x86_sse neon static-libs"
RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r1
!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}
app-arch/xz-utils"
src_prepare() {
default
if use apng; then
eapply -p0 "${WORKDIR}"/${PN}-*-apng.patch
# Don't execute symbols check with apng patch wrt #378111
sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
fi
elibtoolize
}
multilib_src_configure() {
ECONF_SOURCE="${S}" econf \
$(use_enable cpu_flags_x86_sse intel-sse) \
$(use_enable static-libs static) \
--enable-arm-neon=$(usex neon)
}
multilib_src_install_all() {
DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
einstalldocs
prune_libtool_files --all
}
|
GitWeb
