blob: d33afa9ad4bd3eb2aa3885d738a69f2ad39cb9b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit libtool multilib-minimal
DESCRIPTION="Portable Network Graphics library"
HOMEPAGE="http://www.libpng.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
apng? ( mirror://sourceforge/apng/${P}-apng.patch.gz )"
LICENSE="libpng2"
SLOT="0/16"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
IUSE="apng cpu_flags_arm_neon cpu_flags_x86_sse static-libs"
RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}"
src_prepare() {
default
if use apng; then
eapply -p0 "${WORKDIR}"/${PN}-*-apng.patch
# Don't execute symbols check with apng patch wrt #378111
sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
fi
elibtoolize
}
multilib_src_configure() {
local myeconfargs=(
$(use_enable cpu_flags_x86_sse intel-sse)
$(use_enable static-libs static)
--enable-arm-neon=$(usex cpu_flags_arm_neon)
)
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
}
multilib_src_install_all() {
DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
einstalldocs
find "${ED}" \( -type f -o -type l \) -name '*.la' -delete || die
}
|
GitWeb
