blob: 2c95a68cb144b89c3b4f0fb0bd6d23e4e457c016 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit systemd udev
DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
HOMEPAGE="https://alsa-project.org/wiki/Main_Page"
SRC_URI="https://www.alsa-project.org/files/pub/utils/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0.9"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="bat doc +libsamplerate +ncurses nls selinux"
CDEPEND=">=media-libs/alsa-lib-${PV}
libsamplerate? ( media-libs/libsamplerate )
ncurses? ( >=sys-libs/ncurses-5.7-r7:0= )
bat? ( sci-libs/fftw:= )"
DEPEND="${CDEPEND}
doc? ( app-text/xmlto )"
RDEPEND="${CDEPEND}
selinux? ( sec-policy/selinux-alsa )"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-1.2.5-fix-the-nested-iteration.patch # bug #793410
"${FILESDIR}"/${PN}-1.2.5-fix-potential-null-pointer-from-strchr.patch # bug #793410
"${FILESDIR}"/${PN}-1.1.8-missing_header.patch
)
src_configure() {
local myeconfargs=(
# --disable-alsaconf because it doesn't work with sys-apps/kmod wrt #456214
--disable-alsaconf
--disable-maintainer-mode
--with-asound-state-dir="${EPREFIX}"/var/lib/alsa
--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
--with-udev-rules-dir="${EPREFIX}/$(get_udevdir)"/rules.d
$(use_enable bat)
$(use_enable libsamplerate alsaloop)
$(use_enable ncurses alsamixer)
$(use_enable nls)
$(usex doc '' --disable-xmlto)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
dodoc seq/*/README.*
newinitd "${FILESDIR}"/alsasound.initd-r8 alsasound
newconfd "${FILESDIR}"/alsasound.confd-r4 alsasound
insinto /etc/modprobe.d
newins "${FILESDIR}"/alsa-modules.conf-rc alsa.conf
keepdir /var/lib/alsa
# ALSA lib parser.c:1266:(uc_mgr_scan_master_configs) error: could not
# scan directory /usr/share/alsa/ucm: No such file or directory
# alsaucm: unable to obtain card list: No such file or directory
keepdir /usr/share/alsa/ucm
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]]; then
elog
elog "To take advantage of the init script, and automate the process of"
elog "saving and restoring sound-card mixer levels you should"
elog "add alsasound to the boot runlevel. You can do this as"
elog "root like so:"
elog "# rc-update add alsasound boot"
ewarn
ewarn "The ALSA core should be built into the kernel or loaded through other"
ewarn "means. There is no longer any modular auto(un)loading in alsa-utils."
fi
}
|
GitWeb