blob: 26cd9a9238120487829432909cd472d9450ee995 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( lua5-{1..4} luajit )
inherit autotools desktop lua-single xdg
DESCRIPTION="Music player for a wide range of formats designed for gapless playback"
HOMEPAGE="https://aqualung.jeremyevans.net/ https://github.com/jeremyevans/aqualung"
SRC_URI="https://github.com/jeremyevans/${PN}/releases/download/${PV}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate
lua mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray
vorbis wavpack"
REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
BDEPEND="
virtual/pkgconfig
sys-devel/gettext
"
RDEPEND="
app-arch/bzip2
dev-libs/libxml2
sys-libs/zlib
x11-libs/gtk+:2
alsa? ( media-libs/alsa-lib )
cdda? ( dev-libs/libcdio-paranoia )
cddb? ( media-libs/libcddb )
ffmpeg? ( media-video/ffmpeg:0= )
flac? ( media-libs/flac )
ifp? ( media-libs/libifp )
jack? ( virtual/jack )
ladspa? ( media-libs/liblrdf )
lame? ( media-sound/lame )
libsamplerate? ( media-libs/libsamplerate )
lua? ( ${LUA_DEPS} )
mac? ( media-sound/mac )
modplug? ( media-libs/libmodplug )
mp3? ( media-libs/libmad )
musepack? ( >=media-sound/musepack-tools-444 )
pulseaudio? ( media-sound/pulseaudio )
sndfile? ( media-libs/libsndfile )
speex? ( media-libs/speex media-libs/liboggz media-libs/libogg )
vorbis? ( media-libs/libvorbis media-libs/libogg )
wavpack? ( media-sound/wavpack )
"
DEPEND="
${RDEPEND}
"
PATCHES=(
"${FILESDIR}/${P}-configure-lua-version.patch"
"${FILESDIR}/${P}-ifp.patch"
"${FILESDIR}/${P}-var-collision.patch"
)
pkg_setup() {
use lua && lua-single_pkg_setup
}
src_prepare() {
default
eautoreconf
}
src_configure() {
econf \
--disable-rpath \
--enable-loop \
--enable-nls \
--enable-transcoding \
$(use_enable debug) \
$(use_enable podcast) \
$(use_enable systray) \
$(use_enable jack jack-mgmt) \
$(use_with alsa) \
$(use_with cdda) \
$(use_with cddb) \
$(use_with ffmpeg lavc) \
$(use_with flac) \
$(use_with ifp) \
$(use_with jack) \
$(use_with ladspa) \
$(use_with lame) \
$(use_with libsamplerate src) \
$(use_with lua) \
$(use_with mac) \
$(use_with modplug mod) \
$(use_with mp3 mpeg) \
$(use_with musepack mpc) \
$(use_with oss) \
$(use_with pulseaudio pulse) \
$(use_with sndfile) \
$(use_with speex) \
$(use_with vorbis vorbis) \
$(use_with vorbis vorbisenc) \
$(use_with wavpack)
}
src_install() {
default
newicon src/img/icon_64.png aqualung.png
make_desktop_entry aqualung Aqualung
}
|
GitWeb