media-sound/gmorgan/gmorgan-0.79-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit autotools

DESCRIPTION="Opensource software rhythm station"
HOMEPAGE="http://gmorgan.sourceforge.net/"
SRC_URI="mirror://sourceforge/gmorgan/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="nls"

RDEPEND="media-libs/alsa-lib
	x11-libs/fltk:1"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

PATCHES=(
	"${FILESDIR}"/${P}-remove-gettext-version-check.patch
	"${FILESDIR}"/${P}-manpages.patch
	"${FILESDIR}"/${P}-remove-dirs.patch
	"${FILESDIR}"/${P}-remove-old-docs.patch
	"${FILESDIR}"/${P}-gcc6.patch
	"${FILESDIR}"/${P}-clang.patch
)

src_prepare() {
	default
	sed -i -e "s#/usr/local/share/#/usr/share/#" src/gmorgan.chord.cpp || die
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable nls)
}

src_install() {
	default
	doman man/${PN}.1
}