blob: bc0c143c3e97fb75f43dc10a004dcd8bc0d9eb7b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic qmake-utils xdg
DESCRIPTION="Audio/MIDI multi-track sequencer written in C++ with the Qt framework"
HOMEPAGE="https://qtractor.sourceforge.io"
SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aubio cpu_flags_x86_sse debug dssi libsamplerate mad osc rubberband vorbis zlib"
BDEPEND="
dev-qt/linguist-tools:5
virtual/pkgconfig
"
DEPEND="
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
dev-qt/qtx11extras:5
media-libs/alsa-lib
media-libs/ladspa-sdk
media-libs/libsndfile
>=media-libs/lilv-0.16.0
media-libs/lv2
media-libs/suil
virtual/jack
aubio? ( media-libs/aubio )
dssi? ( media-libs/dssi )
libsamplerate? ( media-libs/libsamplerate )
mad? ( media-libs/libmad )
osc? ( media-libs/liblo )
rubberband? ( media-libs/rubberband )
vorbis? ( media-libs/libvorbis )
zlib? ( sys-libs/zlib )
"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}/${P}-dont-compress-manpages.patch"
)
src_configure() {
append-cxxflags -std=c++11
econf \
--enable-ladspa \
--enable-liblilv \
$(use_enable debug) \
$(use_enable aubio libaubio) \
$(use_enable dssi) \
$(use_enable libsamplerate) \
$(use_enable mad libmad) \
$(use_enable osc liblo) \
$(use_enable rubberband librubberband) \
$(use_enable cpu_flags_x86_sse sse) \
$(use_enable vorbis libvorbis) \
$(use_enable zlib libz)
eqmake5 ${PN}.pro -o ${PN}.mak
}
|
GitWeb
