blob: 9ef36a11ada91f7961490811ea165c356d3be49d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake flag-o-matic l10n virtualx xdg
PLOCALES="cs de es fr hu id it ko nb pl ru"
DESCRIPTION="Modern music player and library organizer based on Clementine and Qt"
HOMEPAGE="https://www.strawbs.org/"
if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="https://github.com/jonaski/strawberry.git"
inherit git-r3
else
SRC_URI="https://github.com/jonaski/strawberry/releases/download/${PV}/${P}.tar.xz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-3"
SLOT="0"
IUSE="cdda +dbus debug ipod mms mtp pulseaudio +udisks"
REQUIRED_USE="
udisks? ( dbus )
"
BDEPEND="
dev-qt/linguist-tools:5
sys-devel/gettext
virtual/pkgconfig
"
COMMON_DEPEND="
app-crypt/qca:2[qt5(+)]
dev-db/sqlite:=
dev-libs/glib:2
dev-libs/libxml2
dev-libs/protobuf:=
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5[ssl]
dev-qt/qtsql:5[sqlite]
dev-qt/qtwidgets:5
media-libs/alsa-lib
media-libs/chromaprint:=
media-libs/gstreamer:1.0
media-libs/gst-plugins-base:1.0
>=media-libs/libmygpo-qt-1.0.9[qt5(+)]
>=media-libs/taglib-1.11.1_p20181028
media-video/vlc
sys-libs/zlib
virtual/glu
x11-libs/libX11
cdda? ( dev-libs/libcdio:= )
dbus? ( dev-qt/qtdbus:5 )
ipod? ( >=media-libs/libgpod-0.8.0 )
mtp? ( >=media-libs/libmtp-1.0.0 )
pulseaudio? ( media-sound/pulseaudio )
"
# Note: sqlite driver of dev-qt/qtsql is bundled, so no sqlite use is required; check if this can be overcome someway;
RDEPEND="${COMMON_DEPEND}
media-plugins/gst-plugins-meta:1.0
media-plugins/gst-plugins-soup:1.0
media-plugins/gst-plugins-taglib:1.0
mms? ( media-plugins/gst-plugins-libmms:1.0 )
mtp? ( gnome-base/gvfs[mtp] )
udisks? ( sys-fs/udisks:2 )
"
DEPEND="${COMMON_DEPEND}
>=dev-cpp/gtest-1.8.0
dev-libs/boost
dev-qt/qtopengl:5
dev-qt/qtx11extras:5
dev-qt/qtxml:5
"
DOCS=( Changelog README.md )
src_prepare() {
l10n_find_plocales_changes "src/translations" "" ".po"
cmake_src_prepare
rm -r 3rdparty/taglib || die
}
src_configure() {
# spotify is not in portage
local mycmakeargs=(
-DBUILD_WERROR=OFF
# avoid automagically enabling of ccache (bug #611010)
-DCCACHE_EXECUTABLE=OFF
-DENABLE_GIO=ON
-DLINGUAS="$(l10n_get_locales)"
-DENABLE_AUDIOCD="$(usex cdda)"
-DCMAKE_DISABLE_FIND_PACKAGE_Qt5DBus=$(usex !dbus)
-DENABLE_LIBGPOD="$(usex ipod)"
-DENABLE_LIBMTP="$(usex mtp)"
-DENABLE_LIBPULSE="$(usex pulseaudio)"
-DENABLE_UDISKS2="$(usex udisks)"
-DUSE_SYSTEM_TAGLIB=ON
)
use !debug && append-cppflags -DQT_NO_DEBUG_OUTPUT
cmake_src_configure
}
pkg_postinst() {
xdg_pkg_postinst
elog "Note that list of supported formats is controlled by media-plugins/gst-plugins-meta "
elog "USE flags. You may be interested in setting aac, flac, mp3, ogg or wavpack USE flags "
elog "depending on your preferences"
}
|
GitWeb