blob: ec4e011b9c8310d5562b5772bc7382312fa8422d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools flag-o-matic
DESCRIPTION="Open source SIP, Media, and NAT Traversal Library"
HOMEPAGE="https://www.pjsip.org/"
SRC_URI="https://www.pjsip.org/release/${PV}/${P}.tar.bz2"
KEYWORDS="amd64 ~ppc x86"
LICENSE="GPL-2"
SLOT="0"
CODEC_FLAGS="g711 g722 g7221 gsm ilbc speex l16"
VIDEO_FLAGS="sdl ffmpeg v4l2 openh264 libyuv"
SOUND_FLAGS="alsa oss portaudio"
IUSE="amr debug doc epoll examples ipv6 libressl opus resample silk ssl static-libs webrtc ${CODEC_FLAGS} ${VIDEO_FLAGS} ${SOUND_FLAGS}"
PATCHES=(
"${FILESDIR}"/${P}-ssl-flipflop.patch
"${FILESDIR}"/${P}-libressl.patch
)
RDEPEND="alsa? ( media-libs/alsa-lib )
oss? ( media-libs/portaudio[oss] )
portaudio? ( media-libs/portaudio )
amr? ( media-libs/opencore-amr )
gsm? ( media-sound/gsm )
ilbc? ( media-libs/libilbc )
opus? ( media-libs/opus )
speex? ( media-libs/speexdsp )
ffmpeg? ( media-video/ffmpeg:= )
sdl? ( media-libs/libsdl )
openh264? ( media-libs/openh264 )
resample? ( media-libs/libsamplerate )
ssl? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
)
net-libs/libsrtp:0"
DEPEND="${RDEPEND}
virtual/pkgconfig
!!media-plugins/mediastreamer-bcg729"
REQUIRED_USE="?? ( ${SOUND_FLAGS} )"
src_prepare() {
default
rm configure || die "Unable to remove unwanted wrapper"
mv aconfigure.ac configure.ac || die "Unable to rename configure script source"
eautoreconf
}
src_configure() {
local myconf=()
local videnable="--disable-video"
local t
use ipv6 && append-cflags -DPJ_HAS_IPV6=1
use debug || append-cflags -DNDEBUG=1
for t in ${CODEC_FLAGS}; do
myconf+=( $(use_enable ${t} ${t}-codec) )
done
for t in ${VIDEO_FLAGS}; do
myconf+=( $(use_enable ${t}) )
use "${t}" && videnable="--enable-video"
done
econf \
--enable-shared \
--with-external-srtp \
${videnable} \
$(use_enable epoll) \
$(use_with gsm external-gsm) \
$(use_with speex external-speex) \
$(use_enable speex speex-aec) \
$(use_enable resample) \
$(use_enable resample libsamplerate) \
$(use_enable resample resample-dll) \
$(use_enable alsa sound) \
$(use_enable oss) \
$(use_with portaudio external-pa) \
$(use_enable portaudio ext-sound) \
$(use_enable amr opencore-amr) \
$(use_enable silk) \
$(use_enable opus) \
$(use_enable ssl) \
$(use_enable webrtc libwebrtc) \
"${myconf[@]}"
}
src_compile() {
emake dep
emake
}
src_install() {
emake DESTDIR="${D}" install
if use doc; then
dodoc README.txt README-RTEMS
fi
if use examples; then
insinto "/usr/share/doc/${PF}/examples"
doins -r pjsip-apps/src/samples
fi
use static-libs || rm "${D}/usr/$(get_libdir)/*.a"
}
|
GitWeb