blob: 2ec67e1d40633cdf2b6c8a73c0cafec1e6350e97 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_REQ_USE="xml(+)"
PYTHON_COMPAT=( python3_{8..11} )
inherit gnome2 python-any-r1 vala virtualx
DESCRIPTION="GLib bindings for the Telepathy D-Bus protocol"
HOMEPAGE="https://telepathy.freedesktop.org/"
SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~ia64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
IUSE="debug +introspection +vala"
REQUIRED_USE="vala? ( introspection )"
# Broken for a long time and upstream doesn't care
# https://bugs.freedesktop.org/show_bug.cgi?id=63212
RESTRICT="test"
RDEPEND="
>=dev-libs/glib-2.36:2
>=dev-libs/dbus-glib-0.90
introspection? ( >=dev-libs/gobject-introspection-1.30 )
"
DEPEND="${RDEPEND}
vala? ( $(vala_depend) )
"
BDEPEND="
${PYTHON_DEPS}
dev-libs/libxslt
dev-util/glib-utils
dev-util/gtk-doc-am
virtual/pkgconfig
"
# See bug 504744 for reference
PDEPEND="
net-im/telepathy-mission-control
"
src_prepare() {
use vala && vala_src_prepare
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
--disable-static \
--disable-installed-tests \
$(use_enable debug backtrace) \
$(use_enable debug debug-cache) \
$(use_enable introspection) \
$(use_enable vala vala-bindings)
}
src_test() {
unset DBUS_SESSION_BUS_ADDRESS
# Needs dbus for tests (auto-launched)
virtx emake -j1 check
}
|
GitWeb
