blob: 62482f69489b8e54b102f54505781faf62399814 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DESCRIPTION="GNU Wget2 is a file and recursive website downloader"
HOMEPAGE="https://gitlab.com/gnuwget/wget2"
SRC_URI="mirror://gnu/wget/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0/0" # subslot = libwget.so version
QA_PKGCONFIG_VERSION="2.1.0" # libwget pkg-config versioning
KEYWORDS="~amd64 ~x86"
IUSE="brotli bzip2 doc +gnutls gpgme +http2 idn lzip lzma openssl pcre psl +ssl test valgrind xattr zlib"
REQUIRED_USE="valgrind? ( test )"
RDEPEND="
brotli? ( app-arch/brotli )
bzip2? ( app-arch/bzip2 )
!gnutls? ( dev-libs/libgcrypt:= )
ssl? (
gnutls? ( net-libs/gnutls:= )
!gnutls? (
dev-libs/openssl:0=
)
)
gpgme? (
app-crypt/gpgme:=
dev-libs/libassuan
dev-libs/libgpg-error
)
http2? ( net-libs/nghttp2 )
idn? ( net-dns/libidn2:= )
lzip? ( app-arch/lzlib )
lzma? ( app-arch/xz-utils )
pcre? ( dev-libs/libpcre2 )
psl? ( net-libs/libpsl )
xattr? ( sys-apps/attr )
zlib? ( sys-libs/zlib )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
doc? ( app-doc/doxygen[dot] )
valgrind? ( dev-util/valgrind )
"
RESTRICT="!test? ( test )"
src_configure() {
local myeconfargs=(
--disable-static
--with-plugin-support
--with-ssl="$(usex ssl $(usex gnutls gnutls openssl) none)"
--without-libidn
--without-libmicrohttpd
$(use_enable doc)
$(use_enable valgrind valgrind-tests)
$(use_enable xattr)
$(use_with brotli brotlidec)
$(use_with bzip2)
$(use_with gpgme)
$(use_with http2 libnghttp2)
$(use_with idn libidn2)
$(use_with lzip)
$(use_with lzma)
$(use_with pcre libpcre2)
$(use_with psl libpsl)
$(use_with zlib)
# Avoid calling ldconfig
LDCONFIG=:
)
econf "${myeconfargs[@]}"
}
src_install() {
default
if [[ ${PV} == *9999 ]] ; then
if use doc ; then
local mpage
for mpage in $(find docs/man -type f -regextype grep -regex ".*\.[[:digit:]]$") ; do
doman ${mpage}
done
fi
else
doman docs/man/man{1/*.1,3/*.3}
fi
find "${D}" -type f -name '*.la' -delete || die
rm "${ED}"/usr/bin/${PN}_noinstall || die
}
|
GitWeb