blob: 6ea8ff1593c3c0a30cf7a0975fc44996d66e6fd0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} )
inherit bash-completion-r1 distutils-r1 git-r3 readme.gentoo-r1
DESCRIPTION="Download videos from YouTube.com (and more sites...)"
HOMEPAGE="https://youtube-dl.org/ https://github.com/ytdl-org/youtube-dl/"
EGIT_REPO_URI="https://github.com/ytdl-org/${PN}.git"
LICENSE="public-domain"
SLOT="0"
RDEPEND="
dev-python/pycryptodome[${PYTHON_USEDEP}]
"
distutils_enable_tests nose
src_prepare() {
sed -i -e '/flake8/d' Makefile || die
distutils-r1_src_prepare
}
src_compile() {
distutils-r1_src_compile
emake youtube-dl.{bash-completion,fish,zsh}
}
python_test() {
emake offlinetest
}
python_install_all() {
# no manpage because it requires pandoc to generate
newbashcomp youtube-dl.bash-completion youtube-dl
insinto /usr/share/zsh/site-functions
newins youtube-dl.zsh _youtube-dl
insinto /usr/share/fish/vendor_completions.d
doins youtube-dl.fish
distutils-r1_python_install_all
rm -r "${ED}"/usr/etc || die
rm -r "${ED}"/usr/share/doc/youtube_dl || die
}
pkg_postinst() {
if ! has_version media-video/ffmpeg; then
elog "${PN} works fine on its own on most sites. However, if you want"
elog "to convert video/audio, you'll need media-video/ffmpeg."
elog "On some sites - most notably YouTube - videos can be retrieved in"
elog "a higher quality format without sound. ${PN} will detect whether"
elog "ffmpeg is present and automatically pick the best option."
fi
if ! has_version media-video/rtmpdump; then
elog
elog "Videos or video formats streamed via RTMP protocol can only be"
elog "downloaded when media-video/rtmpdump is installed."
fi
if ! has_version media-video/mplayer && ! has_version media-video/mpv; then
elog
elog "Downloading MMS and RTSP videos requires either media-video/mplayer"
elog "or media-video/mpv to be installed."
fi
if ! has_version media-video/atomicparsley; then
elog
elog "Install media-video/atomicparsley if you want ${PN} to embed thumbnails"
elog "from the metadata into the resulting MP4/M4A files."
fi
}
|
GitWeb