blob: d3424a06eb41d8c891f6d16bc1f7d2dd3165ef73 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
# Copyright 2006-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake systemd xdg-utils
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/transmission/transmission"
else
MY_PV="${PV/_beta/-beta.}"
MY_P="${PN}-${MY_PV}+r634b1e8fc1"
S="${WORKDIR}/${MY_P}"
SRC_URI="https://github.com/transmission/transmission/releases/download/${MY_PV}/${MY_P}.tar.xz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
fi
DESCRIPTION="A fast, easy, and free BitTorrent client"
HOMEPAGE="https://transmissionbt.com/"
# web/LICENSE is always GPL-2 whereas COPYING allows either GPL-2 or GPL-3 for the rest
# transmission in licenses/ is for mentioning OpenSSL linking exception
# MIT is in several libtransmission/ headers
LICENSE="|| ( GPL-2 GPL-3 Transmission-OpenSSL-exception ) GPL-2 MIT"
SLOT="0"
IUSE="appindicator cli gtk nls mbedtls qt5 systemd test"
RESTRICT="!test? ( test )"
ACCT_DEPEND="
acct-group/transmission
acct-user/transmission
"
BDEPEND="${ACCT_DEPEND}
virtual/pkgconfig
nls? (
gtk? ( sys-devel/gettext )
qt5? ( dev-qt/linguist-tools:5 )
)
"
COMMON_DEPEND="
>=dev-libs/libevent-2.1.0:=
!mbedtls? ( dev-libs/openssl:0= )
mbedtls? ( net-libs/mbedtls:0= )
net-libs/libnatpmp
>=net-libs/libpsl-0.21.1
>=net-libs/miniupnpc-1.7:=
>=net-misc/curl-7.28.0[ssl]
sys-libs/zlib:=
nls? ( virtual/libintl )
gtk? (
>=dev-cpp/gtkmm-3.24.0:3.0
>=dev-cpp/glibmm-2.60.0:2
appindicator? ( dev-libs/libayatana-appindicator )
)
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
dev-qt/qtnetwork:5
dev-qt/qtdbus:5
)
systemd? ( >=sys-apps/systemd-209:= )
"
DEPEND="${COMMON_DEPEND}
nls? ( virtual/libintl )
"
RDEPEND="${COMMON_DEPEND}
${ACCT_DEPEND}
"
src_prepare() {
cmake_src_prepare
# https://github.com/transmission/transmission/issues/3901
rm -f libtransmission/version.h || die
}
src_configure() {
local mycmakeargs=(
-DCMAKE_INSTALL_DOCDIR=share/doc/${PF}
-DENABLE_GTK=$(usex gtk ON OFF)
-DENABLE_QT=$(usex qt5 ON OFF)
-DENABLE_MAC=OFF
-DENABLE_WEB=OFF
-DENABLE_CLI=$(usex cli ON OFF)
-DENABLE_TESTS=$(usex test ON OFF)
-DENABLE_NLS=$(usex nls ON OFF)
-DRUN_CLANG_TIDY=OFF
-DUSE_GTK_VERSION=3
-DUSE_SYSTEM_EVENT2=ON
-DUSE_SYSTEM_DEFLATE=OFF
-DUSE_SYSTEM_DHT=OFF
-DUSE_SYSTEM_MINIUPNPC=ON
-DUSE_SYSTEM_NATPMP=ON
-DUSE_SYSTEM_UTP=OFF
-DUSE_SYSTEM_B64=OFF
-DUSE_SYSTEM_PSL=ON
-DUSE_QT_VERSION=5
-DWITH_CRYPTO=$(usex mbedtls mbedtls openssl)
-DWITH_INOTIFY=ON
-DWITH_APPINDICATOR=$(usex appindicator ON OFF)
-DWITH_SYSTEMD=$(usex systemd ON OFF)
)
cmake_src_configure
}
src_install() {
cmake_src_install
newinitd "${FILESDIR}"/transmission-daemon.initd.10 transmission-daemon
newconfd "${FILESDIR}"/transmission-daemon.confd.4 transmission-daemon
if use systemd; then
# Service sets Type=notify
systemd_dounit daemon/transmission-daemon.service
systemd_install_serviced "${FILESDIR}"/transmission-daemon.service.conf
fi
insinto /usr/lib/sysctl.d
doins "${FILESDIR}"/60-transmission.conf
if [[ ${EUID} == 0 ]]; then
diropts -o transmission -g transmission
fi
keepdir /var/lib/transmission
}
pkg_postrm() {
if use gtk || use qt5; then
xdg_desktop_database_update
xdg_icon_cache_update
fi
}
pkg_postinst() {
if use gtk || use qt5; then
xdg_desktop_database_update
xdg_icon_cache_update
fi
}
|
GitWeb