blob: 1c43a235a7e405902e7e1607d5edc5016d2289b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} )
inherit distutils-r1
DESCRIPTION="Astronomical routines for the Python programming language"
HOMEPAGE="https://rhodesmill.org/pyephem/"
SRC_URI="https://github.com/brandon-rhodes/pyephem/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="doc"
BDEPEND="doc? ( dev-python/sphinx )"
distutils_enable_tests pytest
src_prepare() {
# Don't install rst files by default
sed -i -e "s:'doc/\*\.rst',::" setup.py || die
distutils-r1_src_prepare
}
src_compile() {
distutils-r1_src_compile
if use doc; then
PYTHONPATH=. emake -C ephem/doc html
fi
}
python_test() {
cd "${T}" || die
epytest --pyargs ephem
}
src_install() {
use doc && HTML_DOCS=( ephem/doc/_build/html/. )
distutils-r1_src_install
}
python_install() {
distutils-r1_python_install
rm -r "${D}$(python_get_sitedir)/ephem/tests" || die
}
|
GitWeb
