blob: fb7b410ebb3e1dd5674f229648420ee2c5dee89d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="Library for reading TIFF files with embedded tags for geographic information"
HOMEPAGE="https://trac.osgeo.org/geotiff/ https://github.com/OSGeo/libgeotiff"
SRC_URI="https://download.osgeo.org/geotiff/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0/5"
KEYWORDS="amd64 ~arm arm64 ~ia64 ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
IUSE="debug doc"
BDEPEND="
doc? ( app-doc/doxygen )
virtual/pkgconfig
"
DEPEND="
>=media-libs/tiff-3.9.1:0
>=sci-libs/proj-6.0.0:=
sys-libs/zlib
virtual/jpeg:=
"
RDEPEND="${DEPEND}"
src_prepare() {
default
sed -e "s:-O3::g" -i configure.ac || die
eautoreconf
}
src_configure() {
econf \
--disable-static \
--enable-debug=$(usex debug) \
--with-jpeg="${EPREFIX}"/usr \
--with-zip="${EPREFIX}"/usr
}
src_compile() {
default
if use doc; then
mkdir -p docs/api || die
cp "${FILESDIR}"/Doxyfile Doxyfile || die
doxygen -u Doxyfile || die "updating doxygen config failed"
doxygen Doxyfile || die "docs generation failed"
fi
}
src_install() {
use doc && local HTML_DOCS=( docs/api/. )
default
find "${D}" -name '*.la' -type f -delete || die
}
|
GitWeb
