blob: dc16ccdb4491497d3c9b6579c4a86dce89721d0a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic toolchain-funcs
DESCRIPTION="Continuous Collision Detection and Physics Library"
HOMEPAGE="https://pybullet.org/wordpress/"
SRC_URI="https://github.com/bulletphysics/${PN}3/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="ZLIB"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
IUSE="doc double-precision examples extras openmp tbb test +threads"
REQUIRED_USE="
openmp? ( threads )
tbb? ( threads )
"
RDEPEND="
virtual/opengl
media-libs/freeglut
tbb? ( <dev-cpp/tbb-2021.4.0:= )
"
DEPEND="${RDEPEND}"
BDEPEND="doc? ( app-text/doxygen[dot] )"
PATCHES=( "${FILESDIR}"/${PN}-2.85-soversion.patch )
DOCS=( AUTHORS.txt LICENSE.txt README.md )
# Building / linking of third Party library BussIK does not work out of the box
RESTRICT="test"
S="${WORKDIR}/${PN}3-${PV}"
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
src_prepare() {
cmake_src_prepare
# allow to generate docs
sed -i -e 's/GENERATE_HTMLHELP.*//g' Doxyfile || die
}
src_configure() {
# -Werror-strict-aliasing
# https://bugs.gentoo.org/863275
# https://github.com/bulletphysics/bullet3/issues/4590
#
# Do not trust with LTO either
append-flags -fno-strict-aliasing
filter-lto
local mycmakeargs=(
-DBUILD_CPU_DEMOS=OFF
-DBUILD_OPENGL3_DEMOS=OFF
-DBUILD_BULLET2_DEMOS=OFF
-DUSE_GRAPHICAL_BENCHMARK=OFF
-DINSTALL_LIBS=ON
-DBUILD_BULLET3=ON
-DBUILD_BULLET_ROBOTICS_GUI_EXTRA=OFF # This module depends on example libraries
-DBUILD_EXTRAS=$(usex extras)
-DUSE_DOUBLE_PRECISION=$(usex double-precision)
-DBUILD_UNIT_TESTS=$(usex test)
-DBULLET2_MULTITHREADING=$(usex threads)
-DBULLET2_USE_OPEN_MP_MULTITHREADING=$(usex openmp)
-DBULLET2_USE_TBB_MULTITHREADING=$(usex tbb)
)
cmake_src_configure
}
src_compile() {
cmake_src_compile
if use doc; then
doxygen || die
HTML_DOCS+=( html/. )
DOCS+=( docs/*.pdf )
fi
if use examples; then
# throws QA warnings
rm examples/ThirdPartyLibs/openvr/*/linux*/libopenvr_api.so || die
DOCS+=( examples )
fi
}
|
GitWeb