blob: d9188e5e3060b11dc9b71d6f948f455a5304828f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit meson systemd
DESCRIPTION="D-Bus interfaces for querying and manipulating user account information"
HOMEPAGE="https://www.freedesktop.org/wiki/Software/AccountsService/"
SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~ia64 ppc ppc64 ~sparc x86"
IUSE="doc consolekit elogind gtk-doc +introspection selinux systemd"
REQUIRED_USE="^^ ( consolekit elogind systemd )"
CDEPEND="
>=dev-libs/glib-2.44:2
sys-auth/polkit
consolekit? ( sys-auth/consolekit )
elogind? ( >=sys-auth/elogind-229.4 )
introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
systemd? ( >=sys-apps/systemd-186:0= )
"
DEPEND="${CDEPEND}"
BDEPEND="
dev-libs/libxslt
dev-util/gdbus-codegen
sys-devel/gettext
virtual/pkgconfig
doc? (
app-text/docbook-xml-dtd:4.1.2
app-text/xmlto )
gtk-doc? (
dev-util/gtk-doc
app-text/docbook-xml-dtd:4.3 )
"
RDEPEND="${CDEPEND}
selinux? ( sec-policy/selinux-accountsd )
"
PATCHES=(
"${FILESDIR}"/${PN}-0.6.35-gentoo-system-users.patch
)
src_configure() {
local emesonargs=(
--localstatedir="${EPREFIX}/var"
-Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
-Dadmin_group="wheel"
$(meson_use systemd)
$(meson_use elogind)
$(meson_use introspection)
$(meson_use doc docbook)
$(meson_use gtk-doc gtk_doc)
)
meson_src_configure
}
src_install() {
meson_src_install
# https://gitlab.freedesktop.org/accountsservice/accountsservice/-/issues/90
if use doc; then
mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/doc/${PF}" || die
fi
# This directories are created at runtime when needed
rm -r "${ED}"/var/lib || die
}
|
GitWeb
