blob: 574b2739f3a01f168f74b958dfbf39d9700c8e78 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit multilib
DESCRIPTION="Symlinks to use Clang on GCC-free system"
HOMEPAGE="https://wiki.gentoo.org/wiki/Project:LLVM"
SRC_URI=""
S=${WORKDIR}
LICENSE="public-domain"
SLOT="${PV}"
KEYWORDS="~loong"
IUSE="gcc-symlinks multilib-symlinks +native-symlinks"
# Blocker for bug #872416
RDEPEND="
!<sys-devel/gcc-config-2.6
sys-devel/clang:${SLOT}
"
src_install() {
local tools=()
if use native-symlinks; then
tools+=(
cc:clang
cpp:clang-cpp
c++:clang++
)
fi
if use gcc-symlinks; then
tools+=(
gcc:clang
g++:clang++
)
fi
local chosts=( "${CHOST}" )
if use multilib-symlinks; then
local abi
for abi in $(get_all_abis); do
chosts+=( "$(get_abi_CHOST "${abi}")" )
done
fi
local chost t
local dest=/usr/lib/llvm/${SLOT}/bin
dodir "${dest}"
for t in "${tools[@]}"; do
dosym "${t#*:}" "${dest}/${t%:*}"
done
for chost in "${chosts[@]}"; do
for t in "${tools[@]}"; do
dosym "${t#*:}" "${dest}/${chost}-${t%:*}"
done
done
}
|
GitWeb
