x11-misc/splatmoji/splatmoji-1.2.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit optfeature

DESCRIPTION="Quickly look up and input emoji and/or emoticons"
HOMEPAGE="https://github.com/cspeterson/splatmoji/"
SRC_URI="https://github.com/cspeterson/splatmoji/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
KEYWORDS="~amd64"
SLOT="0"
IUSE="test"

RESTRICT="!test? ( test )"

DEPEND="test? (
		app-misc/jq
		dev-util/shunit2
	)"
RDEPEND="
	app-shells/bash
	x11-misc/rofi
	x11-misc/xdotool
	x11-misc/xsel"

src_test() {
	./test/unit_tests || die
}

src_install() {
	dobin splatmoji

	insinto /etc/xdg/splatmoji
	doins splatmoji.config

	insinto /usr/share/splatmoji
	doins -r data

	insinto /usr/lib/splatmoji
	doins lib/functions
}

pkg_postinst() {
	optfeature "JSON-style output" app-misc/jq
}