Add net-analyzer/wireshark-2.4.6

2 files changed, 309 insertions, 0 deletions

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index 3f00f806..907ac425 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -9,6 +9,7 @@ DIST wireshark-2.2.7.tar.bz2 32309420 BLAKE2B a4ec32fab15235c5bde9f03ceafc576005
 DIST wireshark-2.4.2.tar.xz 28791712 BLAKE2B 64a965f522478e2e5690a4439554764bd341c0b8017003af4b0d328094cf56a72462df9dfdb9c9318e4bfc1fe57e4caedc43e0d0c18c704c8342dbb3baa36d91 SHA512 212964482a1e45af490ef78b3f2465384f84c007a76c3a99e8de0e2c37d933fb34b0da5631f4a36ca12d2fa7cc4376d3d405cbe7f7113791ea09dba7e5915417
 DIST wireshark-2.4.3.tar.xz 28807920 BLAKE2B 831691d084fc9ed6198b23c0347efa487398df37ca0cf5972db64b0724fad04b3104a5faed104b5d4b560254b19a2e41118c8d7b71cce785f38ede077215e80f SHA512 4344b9efeda3afba4b13bb468f7a12c4565da96c6182a8203cc5815baa11e7d84f3f11003b4289c6c11391cfb590b8c0319268196cc646a8f0226c432e9bb433
 DIST wireshark-2.4.5.tar.xz 28836740 BLAKE2B 797540daca259a2d5d7dc6e637f2b504b6d14191af4040e6b344c95db6c776b7de80c25c59c98ab84d0337cc96c7313b42c13103a3c3944768a793130deae258 SHA512 2f2c201d6b8a37dcbe03bc9affbf97d632d8e40e4fe5b3a3e79cbd5cfbeb5b9111919850546ccae355fcb042def3456438eb1c4d73f7d56d373e7898311b42f3
+DIST wireshark-2.4.6.tar.xz 28851192 BLAKE2B 19a69d077b794ab07fbfb22b7cf9e61ff54ded5dcd0396ba97d1cbd99addaeb9670d5a870f5e83c39384230def04c078d676580bded81746753716cb392ee05a SHA512 171047fa36a6cb29d1edb8e28086e24075f8b77581d9f3142fa39af8ae3d6dfe0c2e41a9335ca5d9851578b54ac9e6e74ff5bd92a96af262a5cc7a73857b8b81
 EBUILD wireshark-2.2.5.ebuild 7009 BLAKE2B de8ac83eb7ab6cef093dd9caf1c6d3f00acb26b2c390430e9db449d4d810702b25b5f2c4a22e89edb6c789586ba795fe1b228a7f941fe96f974dbee92f442759 SHA512 11449e44f8027a9f54aa50e50869857161ddd6913481b97edc957e575ac62ecffda1e2f4e0825ba41804736a9c375a7db5f9cf37e7d4de7e697517e65291b652
 EBUILD wireshark-2.2.6.ebuild 7011 BLAKE2B dabc7bfd9841c1a784f9b97cb096830aab9f461cb559e31f0cb625aa46ae08ce2148e180304ae3100d44406d8008864608110cf337f89ffc5c7753eab987a9ef SHA512 b5467bcdeccf633d7c4604b9168b02368bf03f416a9adce162afe6b8eaddc0da98bbfcec83d5fd3c0cac630fa80194d57420c67e44e26e538a27bab292cdb21e
 EBUILD wireshark-2.2.7.ebuild 6999 BLAKE2B 250846bb8af7d0cf12c12f93c0ad216176963dd48deaf161b0b9cae0f417301d03e23e0ae242e3739f3d300448b6e3da9786891a116d9c0ff3df531753a25d97 SHA512 8904e674b8ae7748abe6c412f113467fe52aec35f87f130d09dffdef28655ccdf376b1050a7c45bd01dd9166ab63cc9f41f413769097a9a9cf81fa99afe027f8
@@ -16,3 +17,4 @@ EBUILD wireshark-2.4.2.ebuild 7909 BLAKE2B da61730c543d83b39d76614ab90b60de5e25e
 EBUILD wireshark-2.4.3-r1.ebuild 7950 BLAKE2B 0afa404f0efcfc21fb1cef0129907f25b34cf74aeaa945950094fc4846b7ed326a96be574848c50a4b326e0ac705e245124c6ff850fed35ad30773b9e8228c06 SHA512 901e05010d440aeb17920d1da7244564d1c9f8abc4b9212a291290f0d8d85f548f1e8b35918fcdb43486935a1f95593dc30e7c049306fd65fdf720890cf89e71
 EBUILD wireshark-2.4.3.ebuild 7995 BLAKE2B 7c520acffc4f8485f82ebc248918c34855e7630a9b0113f3553b430ac1abf638e8285511ba9536a982970c496fa33bb89b02d04e3192e5cb877badcb7d9f0430 SHA512 fcf6a6d86373c37765b5dbcd0e8f0bfa3aca748b87bc3f19ed80070e61fc09c9856481e1864545d3117e894444fca23694dbd512d2959df47e706d1f634c2325
 EBUILD wireshark-2.4.5.ebuild 7964 BLAKE2B ed0a2951a0cdfe91d9824ef6de4e47e48a9b2242b327a2126a553d1ab8fe48015e98612ef0181674e20be198871cc9fd401f3759b62621d3eecec28bebbdc39f SHA512 9e6778c7bda6b81b9127304093faef11641e8a61a184cbd03b5a4c766c37519003ff3deb149a9b18f2d4f7ccc73ebb54a6da02874568b7c7a2fe61aab9cf94e5
+EBUILD wireshark-2.4.6.ebuild 7972 BLAKE2B 9977a4584b1f60d50d6835439590358282a9cce14c8f660398499f5124bc4376fbc3445f76afc0f76c81bb8b34269648c3e01af20cbf306b90ec223c14e2228d SHA512 bbde98861834c151027c6e8a2c11dd3ae63620c55499aed3ccad27d258c392b4220bcbe6887ed50e82d84cba08158822f18fd69c967b4ea37bdb675611f7ba5a
diff --git a/net-analyzer/wireshark/wireshark-2.4.6.ebuild b/net-analyzer/wireshark/wireshark-2.4.6.ebuild
new file mode 100644
index 00000000..4ca8ea55
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-2.4.6.ebuild
@@ -0,0 +1,307 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils fcaps flag-o-matic gnome2-utils multilib qmake-utils user xdg-utils
+
+DESCRIPTION="A network protocol analyzer formerly known as ethereal"
+HOMEPAGE="https://www.wireshark.org/"
+SRC_URI="${HOMEPAGE}download/src/all-versions/${P/_/}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~ppc ~ppc64 x86 ~x86-fbsd"
+IUSE="
+	adns androiddump +capinfos +caps +captype ciscodump cpu_flags_x86_sse4_2 crypt
+	+dftest doc doc-pdf +dumpcap +editcap geoip gtk kerberos libssh libxml2 lua
+	lz4 +mergecap +netlink nghttp2 +pcap portaudio +qt5 +randpkt +randpktdump
+	+reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl +text2pcap
+	tfshark +tshark +udpdump zlib
+"
+REQUIRED_USE="
+	ciscodump? ( libssh )
+	sshdump? ( libssh )
+	ssl? ( crypt )
+"
+
+S=${WORKDIR}/${P/_/}
+
+CDEPEND="
+	>=dev-libs/glib-2.14:2
+	crypt? ( dev-libs/libgcrypt:0 )
+	netlink? ( dev-libs/libnl:3 )
+	adns? ( >=net-dns/c-ares-1.5 )
+	caps? ( sys-libs/libcap )
+	geoip? ( dev-libs/geoip )
+	gtk? (
+		x11-libs/gdk-pixbuf
+		x11-libs/gtk+:3
+		x11-libs/pango
+		x11-misc/xdg-utils
+	)
+	kerberos? ( virtual/krb5 )
+	libssh? ( >=net-libs/libssh-0.6 )
+	libxml2? ( dev-libs/libxml2 )
+	lua? ( >=dev-lang/lua-5.1:* )
+	lz4? ( app-arch/lz4 )
+	nghttp2? ( net-libs/nghttp2 )
+	pcap? ( net-libs/libpcap )
+	portaudio? ( media-libs/portaudio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+		|| (
+			media-libs/speexdsp
+			<media-libs/speex-1.2.0
+		)
+		x11-misc/xdg-utils
+	)
+	sbc? ( media-libs/sbc )
+	smi? ( net-libs/libsmi )
+	snappy? ( app-arch/snappy )
+	spandsp? ( media-libs/spandsp )
+	ssl? ( net-libs/gnutls:= )
+	zlib? ( sys-libs/zlib !=sys-libs/zlib-1.2.4 )
+"
+# We need perl for `pod2html`.  The rest of the perl stuff is to block older
+# and broken installs. #455122
+DEPEND="
+	${CDEPEND}
+	dev-lang/perl
+	!<virtual/perl-Pod-Simple-3.170
+	!<perl-core/Pod-Simple-3.170
+	doc? (
+		app-doc/doxygen
+		app-text/asciidoc
+		dev-libs/libxml2
+		dev-libs/libxslt
+		doc-pdf? ( dev-java/fop )
+		www-client/lynx
+	)
+	qt5? (
+		dev-qt/linguist-tools:5
+	)
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+RDEPEND="
+	${CDEPEND}
+	gtk? ( virtual/freedesktop-icon-theme )
+	qt5? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.99.8-qtchooser.patch
+	"${FILESDIR}"/${PN}-2.1.0-sse4_2-r1.patch
+	"${FILESDIR}"/${PN}-2.4-androiddump.patch
+	"${FILESDIR}"/${PN}-99999999-androiddump.patch
+	"${FILESDIR}"/${PN}-2.4.3-libsmi.patch
+)
+
+pkg_setup() {
+	enewgroup wireshark
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				myconf+=( "--with-ssl" )
+				;;
+		esac
+	fi
+
+	# Enable wireshark binary with any supported GUI toolkit (bug #473188)
+	if use gtk || use qt5; then
+		myconf+=( "--enable-wireshark" )
+	else
+		myconf+=( "--disable-wireshark" )
+	fi
+
+	if ! use qt5; then
+		myconf+=( "--with-qt=no" )
+	fi
+
+	if use qt5; then
+		export QT_MIN_VERSION=5.3.0
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	# Using '-isysroot' to use the macOS SDK fails due to stub libraries and
+	# missing headers...
+	sed -e '/SDKFLAGS="-isysroot $SDKPATH"/d' \
+		-i macosx-setup.sh \
+	|| die "Could not remove sysroot/SDK injection from macOS setup script: ${?}"
+	sed -e 's/ -isysroot $SDKPATH / /g' \
+		-i m4/ws_osx.m4 configure \
+	|| die "Could not remove sysroot/SDK injection from m4 macros & configure: ${?}"
+
+	# Hack around inability to disable doxygen/fop doc generation
+	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
+	use doc-pdf || export ac_cv_prog_HAVE_FOP=false
+
+	econf \
+		$(use androiddump && use pcap && echo --enable-androiddump-use-libpcap=yes) \
+		$(use dumpcap && use_with pcap dumpcap-group wireshark) \
+		$(use_enable androiddump) \
+		$(use_enable capinfos) \
+		$(use_enable captype) \
+		$(use_enable ciscodump) \
+		$(use_enable dftest) \
+		$(use_enable dumpcap) \
+		$(use_enable editcap) \
+		$(use_enable mergecap) \
+		$(use_enable randpkt) \
+		$(use_enable randpktdump) \
+		$(use_enable reordercap) \
+		$(use_enable sharkd) \
+		$(use_enable sshdump) \
+		$(use_enable text2pcap) \
+		$(use_enable tfshark) \
+		$(use_enable tshark) \
+		$(use_enable udpdump) \
+		$(use_with adns c-ares) \
+		$(use_with caps libcap) \
+		$(use_with crypt gcrypt) \
+		$(use_with geoip) \
+		$(use_with gtk gtk 3) \
+		$(use_with kerberos krb5) \
+		$(use_with libssh) \
+		$(use_with libxml2) \
+		$(use_with lua) \
+		$(use_with lz4) \
+		$(use_with nghttp2) \
+		$(use_with pcap) \
+		$(use_with portaudio) \
+		$(use_with sbc) \
+		$(use_with smi libsmi) \
+		$(use_with snappy) \
+		$(use_with spandsp) \
+		$(use_with ssl gnutls) \
+		$(use_with zlib) \
+		$(usex cpu_flags_x86_sse4_2 --enable-sse4_2 '') \
+		$(usex netlink --with-libnl=3 --without-libnl) \
+		$(usex qt5 --with-qt=5 '') \
+		$(usex qt5 LRELEASE=$(qt5_get_bindir)/lrelease '') \
+		$(usex qt5 MOC=$(qt5_get_bindir)/moc '') \
+		$(usex qt5 RCC=$(qt5_get_bindir)/rcc '') \
+		$(usex qt5 UIC=$(qt5_get_bindir)/uic '') \
+		--disable-profile-build \
+		--disable-warnings-as-errors \
+		--sysconfdir="${EPREFIX}"/etc/wireshark \
+		${myconf[@]}
+
+	# Remove any remaining macOS SDK usage...
+	find . -name Makefile -exec sed -e 's/ -isysroot [^ ]\+ / /g' -i {} +
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		emake -j1 -C docbook
+		if use doc-pdf; then
+			addpredict "/root/.java"
+			emake -C docbook all-pdf
+		fi
+	fi
+}
+
+src_install() {
+	default
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README{,.bsd,.linux,.macos,.vmware} \
+		doc/{randpkt.txt,README*}
+
+	if use doc; then
+		docinto /usr/share/doc/${PF}/html
+		dodoc -r docbook/{release-notes.html,ws{d,u}g_html{,_chunked}}
+		if use doc-pdf; then
+			docinto /usr/share/doc/${PF}/pdf/
+			dodoc docbook/{developer,user}-guide-{a4,us}.pdf docbook/release-notes.pdf
+		fi
+	fi
+
+	# install headers
+	local wsheader
+	for wsheader in \
+		config.h \
+		epan/*.h \
+		epan/crypt/*.h \
+		epan/dfilter/*.h \
+		epan/dissectors/*.h \
+		epan/ftypes/*.h \
+		epan/wmem/*.h \
+		register.h \
+		wiretap/*.h \
+		ws_diag_control.h \
+		ws_symbol_export.h \
+		wsutil/*.h
+	do
+		insinto /usr/include/wireshark/$( dirname ${wsheader} )
+		doins ${wsheader}
+	done
+
+	#with the above this really shouldn't be needed, but things may be looking in wiretap/ instead of wireshark/wiretap/
+	insinto /usr/include/wiretap
+	doins wiretap/wtap.h
+
+	if use gtk || use qt5; then
+		local c d
+		for c in hi lo; do
+			for d in 16 32 48; do
+				insinto /usr/share/icons/${c}color/${d}x${d}/apps
+				newins image/${c}${d}-app-wireshark.png wireshark.png
+			done
+		done
+		for d in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${d}x${d}/mimetypes
+			newins image/WiresharkDoc-${d}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+
+	# Add group for users allowed to sniff.
+	enewgroup wireshark
+
+	if use dumpcap && use pcap; then
+		fcaps -o 0 -g wireshark -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
+	ewarn "add yourself to the wireshark group. This security measure ensures"
+	ewarn "that only trusted users are allowed to sniff your traffic."
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}