Add sys-libs/pam-1.2.1-r2

2 files changed, 206 insertions, 0 deletions

diff --git a/sys-libs/pam/Manifest b/sys-libs/pam/Manifest
index 85aa2e56..67a9079f 100644
--- a/sys-libs/pam/Manifest
+++ b/sys-libs/pam/Manifest
@@ -10,4 +10,5 @@ DIST Linux-PAM-1.2.1.tar.bz2 1279523 SHA256 342b1211c0d3b203a7df2540a5b03a428a08
 EBUILD pam-1.1.6-r2.ebuild 5959 SHA256 2262076f8c4b8527de2f0d21ff86d409c5f84b8d89a3ad809743aa979a917369 SHA512 8c7083d86fa81cf477fc206738132f55f7d69fb5353958f0ae53658ef7aa1330860d98db0a0fc230c7d9aac2c23fcb411bc7b02cf7872f1f4ba93ecd8be1bdd7 WHIRLPOOL d74cfc683feda636a152ca8ee4d89d2e827be288adc37a9e62ff2436e7950bd72cc7bc52cfd5934caf231f7206f0b35ab307d17ffcf05153f2d26c84cda2c87e
 EBUILD pam-1.1.6-r4.ebuild 5501 SHA256 04e293e2962df0f066b4d366d296fed48db259f74e4a5b0a2348e4ad9739266f SHA512 bc67690a8b2ca42e6ccf2ebbce9046b20a59366192eb1eff2a1e631785e7fad6fc26983d58fea937d6ce3cdcc92623ca8aff0f875947c944fda10e6e47d5b22e WHIRLPOOL 5d9c71f15fe3fb1a562b1343d8da0c33491d838b17c43bb7c1ffa291ddaba2120347e7273c02735d3dd7071d52a34f293904368e61ef61443d15479b064c8a3c
 EBUILD pam-1.1.8-r2.ebuild 6052 SHA256 a7664202c00c36dcdaee5b030ae09fae9b123c369ad9bac3e8ba3399868972ad SHA512 05677aacd42ed1379a3d8900ebfceac052f09a4581588dd56299649d6da8464aed2080f8526e3fbdeb1eb17b0c3479b9ad8b47fb0adb093c62701039e8d9ab45 WHIRLPOOL 0085cd296bab427ed60a8677c844c6fb4e5213694166d3628b5d547b35916339bffa5997d19be2e02d871f99cf6e988491eb9fe2f1ad038ff30ceb2e999c3fe2
+EBUILD pam-1.2.1-r2.ebuild 6288 SHA256 7ae896461a0d524fc3d18dcdecd080a104b6c434a627211bda76dda843a11742 SHA512 2d75730972eca99d943f537ff6c1077cb724d0657898031e3e68c7ac540b6d0ae08e8ab10acd374dadfc447f8f125d1a3283c66edd4ae3d4afe1f3853ade75df WHIRLPOOL 94c0ae6d5effadadb9d15ccd6c4ed23721488612b641c9a1d2a789e9c5b99c6e61292332a8370b147f7a1206a74874f70817867721c05d0c99b0db65845a7972
 EBUILD pam-1.2.1.ebuild 6158 SHA256 0ae8cd70b421b82be94e47b47724c5801cde1efff1b2632a4319ad144fd680e0 SHA512 4d3632180cc095d76536c7058146eb9612bbf6410751c761ea1cbfc39184971c8d1bfefb9557640eb06d6d009fd5f511261763220013fef3b49a70ecb8610e97 WHIRLPOOL 185b57c0817b3b1ba25c9ac82a91bfbaa43b17239b8e769593e874897200626466a0ba5a0c6938df166bce8a6c246319588aa414abf1a5553e583d5b6ce22c79
diff --git a/sys-libs/pam/pam-1.2.1-r2.ebuild b/sys-libs/pam/pam-1.2.1-r2.ebuild
new file mode 100644
index 00000000..d7a5a346
--- /dev/null
+++ b/sys-libs/pam/pam-1.2.1-r2.ebuild
@@ -0,0 +1,205 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit libtool multilib eutils pam toolchain-funcs flag-o-matic db-use fcaps multilib-minimal
+
+MY_PN="Linux-PAM"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Linux-PAM (Pluggable Authentication Modules)"
+HOMEPAGE="http://www.linux-pam.org/ https://fedorahosted.org/linux-pam/"
+SRC_URI="http://www.linux-pam.org/library/${MY_P}.tar.bz2
+	http://www.linux-pam.org/documentation/${MY_PN}-1.2.0-docs.tar.bz2"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-linux ~x86-linux"
+IUSE="audit berkdb cracklib debug nis nls +pie selinux test"
+
+RDEPEND="nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
+	cracklib? ( >=sys-libs/cracklib-2.9.1-r1[${MULTILIB_USEDEP}] )
+	audit? ( >=sys-process/audit-2.2.2[${MULTILIB_USEDEP}] )
+	selinux? ( >=sys-libs/libselinux-2.2.2-r4[${MULTILIB_USEDEP}] )
+	berkdb? ( >=sys-libs/db-4.8.30-r1:=[${MULTILIB_USEDEP}] )
+	nis? ( >=net-libs/libtirpc-0.2.4-r2[${MULTILIB_USEDEP}] )"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2
+	>=sys-devel/flex-2.5.39-r1[${MULTILIB_USEDEP}]
+	nls? ( sys-devel/gettext )
+	nis? ( >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}] )"
+PDEPEND="sys-auth/pambase"
+
+RDEPEND="${RDEPEND}
+	!<sys-apps/openrc-0.11.8
+	!sys-auth/openpam
+	!sys-auth/pam_userdb
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20140508-r7
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+check_old_modules() {
+	local retval="0"
+
+	if sed -e 's:#.*::' "${EROOT}"/etc/pam.d/* 2>/dev/null | fgrep -q pam_stack.so; then
+		eerror ""
+		eerror "Your current setup is using the pam_stack module."
+		eerror "This module is deprecated and no longer supported, and since version"
+		eerror "0.99 is no longer installed, nor provided by any other package."
+		eerror "The package will be built (to allow binary package builds), but will"
+		eerror "not be installed."
+		eerror "Please replace pam_stack usage with proper include directive usage,"
+		eerror "following the PAM Upgrade guide at the following URL"
+		eerror "  https://wiki.gentoo.org/wiki/Project:PAM/Upgrade_to_0.99"
+		eerror ""
+
+		retval=1
+	fi
+
+	if sed -e 's:#.*::' "${EROOT}"/etc/pam.d/* 2>/dev/null | egrep -q 'pam_(pwdb|console)'; then
+		eerror ""
+		eerror "Your current setup is using one or more of the following modules,"
+		eerror "that are not built or supported anymore:"
+		eerror "pam_pwdb, pam_console"
+		eerror "If you are in real need for these modules, please contact the maintainers"
+		eerror "of PAM through https://bugs.gentoo.org/ providing information about its"
+		eerror "use cases."
+		eerror "Please also make sure to read the PAM Upgrade guide at the following URL:"
+		eerror "  https://wiki.gentoo.org/wiki/Project:PAM/Upgrade_to_0.99"
+		eerror ""
+
+		retval=1
+	fi
+
+	return ${retval}
+}
+
+pkg_pretend() {
+	# do not error out, this is just a warning, one could build a binpkg
+	# with old modules enabled.
+	check_old_modules
+}
+
+src_unpack() {
+	# Upstream didn't release a new doc tarball (since nothing changed?).
+	unpack ${MY_PN}-1.2.0-docs.tar.bz2
+	# Update timestamps to avoid regenerating at build time. #569338
+	find -type f -exec touch -r "${T}" {} + || die
+	mv Linux-PAM-1.2.{0,1} || die
+	unpack ${MY_P}.tar.bz2
+}
+
+src_prepare() {
+	elibtoolize
+}
+
+multilib_src_configure() {
+	# Do not let user's BROWSER setting mess us up. #549684
+	unset BROWSER
+
+	# Disable automatic detection of libxcrypt; we _don't_ want the
+	# user to link libxcrypt in by default, since we won't track the
+	# dependency and allow to break PAM this way.
+	export ac_cv_header_xcrypt_h=no
+
+	local myconf=(
+		--docdir='$(datarootdir)'/doc/${PF}
+		--htmldir='$(docdir)/html'
+		--libdir='$(prefix)'/$(get_libdir)
+		--enable-securedir="${EPREFIX}"/$(get_libdir)/security
+		--enable-isadir='.' #464016
+		$(use_enable nls)
+		$(use_enable selinux)
+		$(use_enable cracklib)
+		$(use_enable audit)
+		$(use_enable debug)
+		$(use_enable berkdb db)
+		$(use_enable nis)
+		$(use_enable pie)
+		--with-db-uniquename=-$(db_findver sys-libs/db)
+		--disable-prelude
+		--disable-regenerate-docu
+	)
+
+	ECONF_SOURCE=${S} \
+	econf "${myconf[@]}"
+}
+
+multilib_src_compile() {
+	emake sepermitlockdir="${EPREFIX}/var/run/sepermit"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install \
+		sepermitlockdir="${EPREFIX}/var/run/sepermit"
+
+	local prefix
+	if multilib_is_native_abi; then
+		prefix=
+		gen_usr_ldscript -a pam pamc pam_misc
+	else
+		prefix=/usr
+	fi
+
+	# create extra symlinks just in case something depends on them...
+	local lib
+	for lib in pam pamc pam_misc; do
+		if ! [[ -f "${ED}"${prefix}/$(get_libdir)/lib${lib}$(get_libname) ]]; then
+			dosym lib${lib}$(get_libname 0) ${prefix}/$(get_libdir)/lib${lib}$(get_libname)
+		fi
+	done
+}
+
+DOCS=( CHANGELOG ChangeLog README AUTHORS Copyright NEWS )
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --all
+
+	docinto modules
+	local dir
+	for dir in modules/pam_*; do
+		newdoc "${dir}"/README README."$(basename "${dir}")"
+	done
+
+	if use selinux; then
+		dodir /usr/lib/tmpfiles.d
+		cat - > "${D}"/usr/lib/tmpfiles.d/${CATEGORY}:${PN}:${SLOT}.conf <<EOF
+d /var/run/sepermit 0755 root root
+EOF
+	fi
+}
+
+pkg_preinst() {
+	check_old_modules || die "deprecated PAM modules still used"
+}
+
+pkg_postinst() {
+	ewarn "Some software with pre-loaded PAM libraries might experience"
+	ewarn "warnings or failures related to missing symbols and/or versions"
+	ewarn "after any update. While unfortunate this is a limit of the"
+	ewarn "implementation of PAM and the software, and it requires you to"
+	ewarn "restart the software manually after the update."
+	ewarn ""
+	ewarn "You can get a list of such software running a command like"
+	ewarn "  lsof / | egrep -i 'del.*libpam\\.so'"
+	ewarn ""
+	ewarn "Alternatively, simply reboot your system."
+	if [[ -x "${EROOT}"/var/log/tallylog ]] ; then
+		elog ""
+		elog "Because of a bug present up to version 1.1.1-r2, you have"
+		elog "an executable /var/log/tallylog file. You can safely"
+		elog "correct it by running the command"
+		elog "  chmod -x /var/log/tallylog"
+		elog ""
+	fi
+
+	# The pam_unix module needs to check the password of the user which requires
+	# read access to /etc/shadow only.
+	fcaps cap_dac_override sbin/unix_chkpwd
+}