Introduce a separate ebuild for the first release of systemd-ui.

(Portage version: 2.2.0_alpha96_p5/cvs/Linux x86_64)

1 files changed, 47 insertions, 0 deletions

diff --git a/sys-apps/systemd-ui/systemd-ui-1.ebuild b/sys-apps/systemd-ui/systemd-ui-1.ebuild
new file mode 100644
index 000000000000..0ede5f9a5024
--- /dev/null
+++ b/sys-apps/systemd-ui/systemd-ui-1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/systemd-ui/systemd-ui-1.ebuild,v 1.1 2012/03/31 11:52:03 mgorny Exp $
+
+EAPI=4
+
+inherit autotools-utils
+
+DESCRIPTION="System and service manager for Linux"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/systemd"
+SRC_URI="http://www.freedesktop.org/software/systemd/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+VALASLOT="0.14"
+
+RDEPEND="!sys-apps/systemd[gtk]
+	>=dev-libs/glib-2.26
+	dev-libs/libgee:0
+	sys-apps/dbus
+	x11-libs/gtk+:2
+	>=x11-libs/libnotify-0.7"
+
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	dev-lang/vala:${VALASLOT}"
+
+# Due to vala being broken.
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+src_prepare() {
+	# Force the rebuild of .vala sources
+	touch src/*.vala || die
+
+	# Fix hardcoded path in .vala.
+	sed -i -e 's:/lib/systemd:/usr/lib/systemd:g' src/*.vala || die
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	export VALAC="$(type -p valac-${VALASLOT})"
+	autotools-utils_src_configure
+}